윈도우에서 창 아무곳이나 클릭해 드래그 이동하는 방법

창을_드래그할_수_있는_위치
창을 드래그할 수 있는 위치

윈도우Windows에서 특정 창을 이동할 때 위 이미지에 마킹해둔 위치와 같이 창의 상단 타이틀이 위치한 영역을 클릭해서 드래그해야 합니다. 하지만 브라우저Browser와 같은 앱은 다량의 탭Tab이 생성되면 빈 공간을 찾기가 어렵고 상단 바와 다른 영역의 구분이 불분명한 앱은 그대로 또 클릭 지점을 찾아야합니다.

누군가는 전혀 불편하지 않을 수 있지만 필자는 굳이 상단바를 눌러서 이동하는 것이 번거롭다고 느껴졌는데요. 이 경우 윈도우에서는 오토핫키AutoHotKey를 활용하면 상단 탭 영역이 아닌 창의 아무곳이나 클릭해도 이동할 수 있도록 수정할 수 있습니다. 윈도우 11Windows 11을 기준으로 설명하지만 다른 윈도우 버전에서도 동일하게 동작하기 때문에 그대로 적용 가능합니다. 맥에서 동일한 방식으로 사용하고 싶은 경우 맥에서 창 아무곳이나 클릭해 드래그 이동하는 방법을 참고하세요.

아래 설명은 테스트 및 검증 후 작성 된 내용이지만 이것이 본문의 내용의 정확성이나 신뢰성에 대해 보증을 하는 것은 아니니 단순 하게 참고용으로 확인바랍니다.

튜토리얼 환경: 윈도우 11, AutoHotKey 1.1.34.02

오토핫키 설치

AutoHotKey_다운로드_페이지
AutoHotKey 다운로드 페이지

기본적으로 오토핫키를 이용한 방식이기 때문에 윈도우에서 오토핫키를 설치해야 합니다. 오토핫키를 설치하는 기본적인 방법은 오토핫키 설치 및 사용방법을 확인하세요.

아무곳이나 클릭해 창 이동 설정하기

오토핫키 설치 후 다음에 안내하는 스크립트로 오토핫키 파일을 만들고 실행하면 창의 아무곳이나 클릭해 드래그하여 이동할 수 있습니다.

오토핫키_스크립트_작성
오토핫키 스크립트 작성
  1. 오토핫키를 설치 후 메모장을 열고 다음 스크립트를 작성하거나 붙여넣기( Ctrl + V )후 .ahk 파일로 저장합니다.
!LButton:: ; Alt 키와 마우스 LButton으로 동작

CoordMode, Mouse ; Switch to screen/absolute coordinates.
MouseGetPos, EWD_MouseStartX, EWD_MouseStartY, EWD_MouseWin
WinGetPos, EWD_OriginalPosX, EWD_OriginalPosY,,, ahk_id %EWD_MouseWin%
WinGet, EWD_WinState, MinMax, ahk_id %EWD_MouseWin%

If EWD_WinState = 0 ; Only If the window isn't maximized
 SetTimer, EWD_WatchMouse, 10 ; Track the mouse as the user drags it.
return

EWD_WatchMouse:
GetKeyState, EWD_LButtonState, LButton, P
If EWD_LButtonState = U ; Button has been released, so drag is complete.
{
 SetTimer, EWD_WatchMouse, off
 return
}

GetKeyState, EWD_EscapeState, Escape, P
If EWD_EscapeState = D ; Escape has been pressed, so drag is cancelled.
{
 SetTimer, EWD_WatchMouse, off
 WinMove, ahk_id %EWD_MouseWin%,, %EWD_OriginalPosX%, %EWD_OriginalPosY%
 return
}

CoordMode, Mouse
MouseGetPos, EWD_MouseX, EWD_MouseY
WinGetPos, EWD_WinX, EWD_WinY,,, ahk_id %EWD_MouseWin%
SetWinDelay, -1 ; Makes the below move faster/smoother.

WinMove, ahk_id %EWD_MouseWin%,, EWD_WinX + EWD_MouseX - EWD_MouseStartX, EWD_WinY + EWD_MouseY - EWD_MouseStartY

EWD_MouseStartX := EWD_MouseX ; Update for the next timer-call to this subroutine.
EWD_MouseStartY := EWD_MouseY

return

;reference: https://www.autohotkey.com/docs/scripts/#EasyWindowDrag
  1. 해당 스크립트에는 트리거 키가 존재하는데 트리거 키를 누른 상태에서 이동하고자 하는 창의 아무곳이나 클릭해 드래그하면 상단 바를 클릭한 것과 동일하게 원하는 곳으로 이동할 수 있습니다. 필자의 경우 이 트리거 키를 Alt 키로 지정해 사용중으로 스크립트에서도 해당 키로 지정해 두었습니다. 트리거 키는 본인이 선호하는 키로 변경할 수 있으며 주로 다음 표에 안내하는 보조키를 이용합니다.
기호
Win#
Alt!
Ctrl^
Shift+
참고: 스크립트를 편하게 사용하기 위해서는 윈도우가 시작될 때 자동으로 실행되도록 해야 합니다. 자세한 내용은 윈도우 11에서 시작 프로그램을 등록하는 방법을 확인해보세요.

적용 결과

아무데나_클릭해서_창_드래그가능
아무데나 클릭해서 창 드래그가능


위 과정으로 생성된 .ahk파일을 실행한 뒤 트리거 키로 지정한 Alt를 누른 상태에서 창의 아무곳이나 클릭해 드래그하면 위 영상처럼 창의 위치를 바로 이동할 수 있습니다.

마치며

이번 포스트에서는 오토핫키를 활용해 윈도우에서 창을 이동할 때 상단 바가 아닌 아무곳이나 클릭해서 이동할 수 있도록 수정하는 방법에 대해 알아보았습니다. 이 방식이 처음에는 익숙하지 않아 잘 사용하지 않게 될 수 있지만 조금만 사용해 보면 상당히~ 편리하다는 것을 알 수 있습니다.

동일한 기능을 제공하는 shellenhancer라는 프로그램이 존재하지만 현재 업데이트가 정상적으로 이루어지지 않고 있어 사용을 권장하기는 어렵기 때문에 본 설명의 오토핫키를 이용한 방식이 가장 무난하지 않을까 합니다.

이렇게, 창을 자주 이동하는 경우 위 과정에 안내하는 오토핫키를 활용해 상단 바가 아닌 아무곳이나 클릭해서 이동하도록 설정 후 사용해 보시길 바랍니다.

관련 글

본 글의 저작권은 comeinsidebox.com에 있습니다. comeinsidebox.com의 사전 서면 동의 없이 본 글의 전부 또는 일부를 무단으로 전재, 게시, 배포하는 것을 금지합니다.
댓글로 남기기 어려운 내용은 Contact Form 링크를 이용해 개별적으로 문의 할 수 있습니다. 해당 포스트와 연관 된 문의 시 Copy를 눌러  URL 을 복사 후 등록 해야 합니다.

Leave a Comment